# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit git-r3 eutils meson

DESCRIPTION="i3-compatible Wayland window manager"
HOMEPAGE="http://swaywm.org/"

EGIT_REPO_URI="https://github.com/swaywm/sway.git"
EGIT_BRANCH="master"

LICENSE="MIT"
SLOT="0"
KEYWORDS=""
IUSE="xwayland bash-completion zsh-completion fish-completion systemd elogind"

REQUIRED_USE="systemd? ( !elogind ) elogind? ( !systemd )"

RDEPEND="dev-libs/wlroots[libcap]
	dev-libs/libpcre2
	>=dev-libs/json-c-0.13
	x11-libs/pango
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	virtual/pam
	sys-apps/dbus
	xwayland? ( dev-libs/wlroots[xwayland] )
	systemd? ( dev-libs/wlroots[systemd] )
	elogind? ( dev-libs/wlroots[elogind] )"


DEPEND="${RDEPEND}
	>=dev-util/meson-0.47
	dev-util/ninja
	app-text/scdoc"

src_configure() {
	local emesonargs=(
	    $(meson_use bash-completion)
		$(meson_use zsh-completion)
		$(meson_use fish-completion)
		-Denable-xwayland=$(usex xwayland true false)
		-Ddefault-wallpaper=true
	)
	meson_src_configure
}

src_install() {
	meson_src_install

	use !systemd && use !elogind && fperms u+s /usr/bin/sway
}