sway & wlroots commits

dev-libs/sway/Manifest

@@ -0,0 +1 @@
+EBUILD sway-9999.ebuild 1165 BLAKE2B 29593770a381f7afdc556b829c06158aace8081992b8578dec52139f44ef7c4bafd96ee49095c9072604e14498f1bcb46beb9ca0ca4e41f812383d66b72aecb9 SHA512 45cccce4272df9c37eff7655beaa6ab5c6d6c8f2e760194dccad7566994f3c0696729bc5db0339364793692384380ca457635c19516c39a2d792f0f7caea5aa2

dev-libs/sway/sway-9999.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit git-r3 eutils meson
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="http://swaywm.org/"
+
+EGIT_REPO_URI="https://github.com/swaywm/sway.git"
+EGIT_BRANCH="master"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="xwayland bash-completion zsh-completion fish-completion systemd elogind"
+
+REQUIRED_USE="systemd? ( !elogind ) elogind? ( !systemd )"
+
+RDEPEND="dev-libs/wlroots[libcap]
+	dev-libs/libpcre2
+	>=dev-libs/json-c-0.13
+	x11-libs/pango
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	virtual/pam
+	sys-apps/dbus
+	xwayland? ( dev-libs/wlroots[xwayland] )
+	systemd? ( dev-libs/wlroots[systemd] )
+	elogind? ( dev-libs/wlroots[elogind] )"
+
+
+DEPEND="${RDEPEND}
+	>=dev-util/meson-0.47
+	dev-util/ninja
+	app-text/scdoc"
+
+src_configure() {
+	local emesonargs=(
+	    $(meson_use bash-completion)
+		$(meson_use zsh-completion)
+		$(meson_use fish-completion)
+		-Denable-xwayland=$(usex xwayland true false)
+		-Ddefault-wallpaper=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	use !systemd && use !elogind && fperms u+s /usr/bin/sway
+}

dev-libs/wlroots/Manifest

@@ -0,0 +1 @@
+EBUILD wlroots-9999.ebuild 1470 BLAKE2B 8a09fef952ae56ef5bf723a5a7be052fc10dc7e0efbd1634ebee5af5ef89ef8a959b6d04a2516a6b227605b508071351777ab00711328c74eda4f227343c2ed8 SHA512 fdb257409bb034cf8b3f718a67c01ee1a23db51592a6c01925b09204a4e6ee2e64c98fefdcf63b00d84430ed7ff0d12dfc5725efd2db1815d5f5a01b9765c863

dev-libs/wlroots/wlroots-9999.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit git-r3 eutils meson
+
+DESCRIPTION="A modular Wayland compositor library"
+HOMEPAGE="https://swaywm.org"
+
+EGIT_REPO_URI="https://github.com/swaywm/wlroots.git"
+EGIT_BRANCH="master"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="systemd elogind xwayland x11-backend rootston examples libcap"
+
+REQUIRED_USE="systemd? ( !elogind ) elogind? ( !systemd )"
+
+RDEPEND="dev-libs/wayland
+	dev-libs/wayland-protocols
+	media-libs/mesa[gbm,gles2,wayland]
+	x11-libs/libdrm
+	dev-libs/libinput
+	x11-libs/libxkbcommon
+	virtual/udev
+	x11-libs/pixman
+	systemd? ( sys-apps/systemd )
+	elogind? ( sys-auth/elogind )
+	x11-backend? (
+		x11-libs/libxcb
+		x11-libs/libXfixes
+		x11-libs/libXcomposite
+		x11-libs/libXrender
+		x11-libs/xcb-util-image
+	)
+	xwayland? ( x11-base/xorg-server[wayland] )
+	libcap? ( sys-libs/libcap )"
+
+
+DEPEND="${RDEPEND}
+	>=dev-util/meson-0.47
+	dev-util/ninja"
+
+src_configure() {
+	local emesonargs=(
+		-Dxwayland=$(usex xwayland enabled disabled)
+		-Dlibcap=$(usex libcap enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+		$(meson_use rootston)
+		$(meson_use examples)
+	)
+	if use systemd ; then
+		emesonargs+=(
+			-Dlogind=enabled
+			-Dlogind-provider=systemd
+		)
+	elif use elogind ; then
+		emesonargs+=(
+			-Dlogind=enabled
+			-Dlogind-provider=elogind
+		)
+	else
+		emesonargs+=(
+			-Dlogind=disabled
+		)
+	fi
+	meson_src_configure
+}